Tera Term のススメ

RDP ログイン自動化マクロ

マクロの目的

利用可能環境

Teraterm

マクロの使い方

実行タイミング

マクロの指定方法

ttpmacro.exe を利用する場合

ttermpro.exe を利用する場合

メニューから実行する場合

コード

著作権情報

著作権者

ライセンス

関連情報

コード

ファイルダウンロード

コピペ用

; RDP login macro of Tera Term
;
; File: rdplogin.ttl
; Description: auto login with SSH2 protocol
; Environment: generic
; Update: 2019/6/16
; Author: Kazuya Jimba

;;; 環境設定 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; アクセス先
defaulthost = '192.168.0.1'

;; ポート番号
portnumber = 3389

;; ユーザ情報
defaultuser = 'administrator'

;; ディレクトリ情報
getdir pBaseDir

;; ファイル情報
pPasswdData = 'password.dat'
gettime pLogData "teraterm-rdp-%Y%m%d.log"

;; パス情報
; パスワード暗号化ファイル
makepath pPasswdFile pBaseDir pPasswdData

; Tera Term ログ
makepath pPasswdFile pBaseDir pPasswdData
makepath pLogFile    pBaseDir pLogData

; サブルーチン fnLog 用変数初期化
pOutputLine = ''

; RDP コマンドフルパス確定処理
RDP = "%windir%\system32\mstsc.exe"
expandenv RDP

;;; ログイン情報収集 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

pOutputLine = 'rdplogin.ttl マクロ開始'
call fnLog

inputbox 'ユーザ名を入力してください' 'アカウント入力' defaultuser
username = inputstr

sprintf2 msg "%s でアクセスするホスト名を入力してください。" username
inputbox msg 'ホスト名入力' defaulthost
hostname = inputstr

sprintf2 pPasswdName "%s@%s" username hostname
getpassword pPasswdFile pPasswdName Password

pOutputLine = '情報収集完了'
call fnLog

;;; メイン処理 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

pOutputLine = 'メイン処理開始'
call fnLog

;; Windows OS へのアカウント登録
sprintf2 line "cmdkey /generic:TERMSRV/%s /user:%s /pass:%s" hostname username password
exec line

; 実行コマンドの組み立て
sprintf2 CMD "%s /v:%s:%d" RDP hostname portnumber

sprintf2 pOutputLine "%s へのRDP ログイン実行" hostname
call fnLog

;; ログイン
exec CMD

; 接続中に登録情報を削除してしまうことがあるため、30秒待機します。
; バージョン 4.63 以降に追加された exec のオプション wait は、今回除外しています。

pause 30

; Windows OS に登録したアカウント情報の削除
sprintf2 line "cmdkey /delete:TERMSRV/%s:%d" hostname portnumber
exec line

;;; 終了処理 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

pOutputLine = 'rdplogin.ttl マクロ終了'
call fnLog

end

;;; 関数処理 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

;; マクロログ取得
:fnLog
    ; 変数 pOutputLine の内容をログファイルへ出力するサブルーチン。
    fileopen fhLog pLogFile 1

    ; ログ出力時刻情報取得
    gettime pLogTime "%Y/%m/%d %H:%M:%S"

    ; メッセージ生成
    sprintf2 MsgLine "%s %s" pLogTime pOutputLine

    ; ファイルへ追記して終了
    filewriteln fhLog MsgLine
    fileclose fhLog

return

備考